PROGRAM game_of_life;
(**********************************************************************)
(* Paul Koop M.A. game of life                                        *)
(* Die Simulation wurde ursprunglich entwickelt,                      *)
(* um die Verwendbarkeit von Zellularautomaten                        *)
(* fuer die Algorithmisch Rekursive Sequanzanalyse                    *)
(* zu ueberpruefen								    *)
(* Modellcharakter hat allein der Quelltext. Eine Compilierung        *)
(* dient nur als Falsifikationsversuch                                *)
(**********************************************************************)
USES dos,crt;

(*------------------------------------ Datenstruktur -----------------*)
CONST

 l = char(111);
 t = char(255);
 lebendig = true;

TYPE

 raum = array(.1..80,1..24.) of boolean;
 zahl = ^inhalt;
 inhalt = RECORD
           i:integer;
           v:zahl;
           n:zahl;
          END;
VAR
 a,b:raum;
 n,x,y,xa,ya:zahl;

(*---------------------------------------- Prozeduren ---------------*)
PROCEDURE aufbau;
 VAR z:integer;
 BEGIN
  z := 1;
  new(n);
  xa := n;
  x := n;
  x^.i := z;
  REPEAT
   z := z +1;
   new(n);
   x^.n := n;
   n^.v := x;
   x := n;
   x^.i := z;
  UNTIL z = 80;
  x^.n := xa;
  xa^.v := x;

  z := 1;
  new(n);
  ya := n;
  y := n;
  y^.i := z;
  REPEAT
   z := z +1;
   new(n);
   y^.n := n;
   n^.v := y;
   y := n;
   y^.i := z;
  UNTIL z = 24;
  y^.n := ya;
  ya^.v := y;
 END;

PROCEDURE abbaux(x:zahl);
 BEGIN
  IF x^.n <> xa THEN abbaux(x^.n);
  dispose(x);
 END;

PROCEDURE abbauy(y:zahl);
 BEGIN
  IF y^.n <> ya THEN abbauy(y^.n);
  dispose(y);
 END;

FUNCTION neu (VAR r:raum; VAR x,y:zahl):boolean;
 VAR z:integer;
 BEGIN
  z := 0;
  IF r(.x^.v^.i,y^.v^.i.) THEN z := z +1;
  IF r(.x^.i   ,y^.v^.i.) THEN z := z +1;
  IF r(.x^.n^.i,y^.v^.i.) THEN z := z +1;
  IF r(.x^.v^.i,y^.i   .) THEN z := z +1;
  IF r(.x^.n^.i,y^.i   .) THEN z := z +1;
  IF r(.x^.v^.i,y^.n^.i.) THEN z := z +1;
  IF r(.x^.i   ,y^.n^.i.) THEN z := z +1;
  IF r(.x^.n^.i,y^.n^.i.) THEN z := z +1;

  IF r(.x^.i,y^.i.)
   THEN
    BEGIN
     IF (z >=2)and(z<=3)THEN neu:= lebendig
                     ELSE neu:= not(lebendig)
    END
   ELSE
    BEGIN
     IF (z=3) THEN neu := (lebendig)
              ELSE neu := not(lebendig)
    END
 END;

PROCEDURE text_anfang;
 BEGIN
  window(1,25,80,25);
  textbackground(red);
  textcolor(white);
  clrscr;
  write('Koop Editor <F10>Zufall <Pfeil>Cursor <Einfg>lebendig <Entf>tot <Return>Start');
  gotoxy(1,1);
  textcolor(2);
  textbackground(blue);
  window(1,1,80,24);clrscr;window(1,1,80,25);
 END;

PROCEDURE text_ende;
 BEGIN
  gotoxy(1,25);
  textbackground(red);
  textcolor(white);
  write('Koop Game of life <F1>neu       <F2>Editieren                    <RETURN> Ende');
  gotoxy(1,1);
  textcolor(2);
  textbackground(blue);
 END;

PROCEDURE zufall(VAR von:raum);
 VAR x,y,z:integer;
 BEGIN
  randomize;gotoxy(1,1);
  FOR y := 1 TO 24
   DO
   FOR x := 1 TO 80
    DO
     BEGIN
      z := random(2);
      IF (z = 0) THEN
                  BEGIN
                   von(.x,y.) := lebendig;
                   write(l)
                  END
                 ELSE
                  BEGIN
                   von(.x,y.) := not(lebendig);
                   write(t)
                  END;
     END;
 END;

PROCEDURE editor (VAR von:raum);
 var
    ch1,ch2 : char;
    xz,yz:integer;
    z:boolean;
  begin
  z := not(lebendig);
  randomize;
  text_anfang;
 FOR yz := 1 TO 24
   DO
   FOR xz := 1 TO 80
    DO
     von(.xz,yz.) := not(lebendig);

   x:= xa;
   y:= ya;
   repeat
   ch1 := readkey;
   IF ch1 =#0
    THEN
    BEGIN
     ch2 := readkey;
     CASE ch2 OF
      #68 : BEGIN
             zufall(von);
            END;
      #72 : y:=y^.v;
      #80 : y:=y^.n;
      #75 : x:=x^.v;
      #77 : x:=x^.n;
      #71 : BEGIN
                y := y^.v;
                x := x^.v;
            END;
      #73 : BEGIN
                y := y^.v;
                x := x^.n;
            END;
      #81 : BEGIN
                y := y^.n;
                x := x^.n;
            END;
      #79 : BEGIN
                y := y^.n;
                x := x^.v;
            END;

      #83 : z := not(lebendig);
      #82 : z := lebendig;
     ELSE
      write(char(7))
     END;
    gotoxy(x^.i,y^.i);
    IF z
     THEN
      BEGIN
       von(.x^.i,y^.i.) := lebendig;
       write(l);
       gotoxy(x^.i,y^.i);
      END
     ELSE
      BEGIN
       von(.x^.i,y^.i.) := not(lebendig);
       write(t);
       gotoxy(x^.i,y^.i);
      END
    END
    ELSE write(char(7));
   until ch1 = #13;
   text_ende;
 END;


PROCEDURE korrektor (VAR von:raum);
 var
    ch1,ch2 : char;
    xz,yz:integer;
    z:boolean;
  begin
  z := not(lebendig);
  randomize;
  text_anfang;
  gotoxy(1,1);
 FOR yz := 1 TO 24
   DO
   FOR xz := 1 TO 80
    DO
     IF (von(.xz,yz.)=lebendig)
      THEN write(l)
      ELSE write(t);
   gotoxy(1,1);
   x:= xa;
   y:= ya;
   repeat
   ch1 := readkey;
   IF ch1 =#0
    THEN
    BEGIN
     ch2 := readkey;
     CASE ch2 OF
      #68 : BEGIN
             zufall(von);
            END;
      #72 : y:=y^.v;
      #80 : y:=y^.n;
      #75 : x:=x^.v;
      #77 : x:=x^.n;
      #71 : BEGIN
                y := y^.v;
                x := x^.v;
            END;
      #73 : BEGIN
                y := y^.v;
                x := x^.n;
            END;
      #81 : BEGIN
                y := y^.n;
                x := x^.n;
            END;
      #79 : BEGIN
                y := y^.n;
                x := x^.v;
            END;

      #83 : z := not(lebendig);
      #82 : z := lebendig;
     ELSE
      write(char(7))
     END;
    gotoxy(x^.i,y^.i);
    IF z
     THEN
      BEGIN
       von(.x^.i,y^.i.) := lebendig;
       write(l);
       gotoxy(x^.i,y^.i);
      END
     ELSE
      BEGIN
       von(.x^.i,y^.i.) := not(lebendig);
       write(t);
       gotoxy(x^.i,y^.i);
      END
    END
    ELSE write(char(7));
   until ch1 = #13;
   text_ende;
 END;



PROCEDURE spiel(VAR von,nach :raum);
 BEGIN
  y :=ya;
  x :=xa;
  REPEAT
   REPEAT
    nach(.x^.i,y^.i.):=neu(von,x,y);
    IF nach(.x^.i,y^.i.) THEN WRITE(l)
                         ELSE WRITE(t);
    x := x^.n
   UNTIL x =xa;
   y := y^.n
  UNTIL y =ya;
 END;

PROCEDURE hauptprogramm;
 var
    ch1,ch2 : char;
    xz,yz:integer;
  begin
   IF keypressed THEN REPEAT ch1 := readkey UNTIL not(keypressed);
   repeat
   IF keypressed
    THEN
     BEGIN
      ch1 := readkey;
      IF ch1 =#0
       THEN
        BEGIN
         ch2 := readkey;
          CASE ch2 OF
           #59: BEGIN
                 x := xa;
                 abbaux(x);
                 y := ya;
                 abbauy(y);
                 aufbau;
                 editor(a);
                END;
           #60: korrektor(a);
          ELSE
          END;
         END
        ELSE;
     END
    ELSE
    BEGIN
     gotoxy(1,1);
     spiel(a,b);
     gotoxy(1,1);
     spiel(b,a);
    END
   until ch1 = #13;
 END;

(*-------------------------------------- Hauptprogramm -----------------*)
BEGIN
 checkbreak := false;
 aufbau;
 editor(a);
 hauptprogramm;
 x := xa;
 abbaux(x);
 y := ya;
 abbauy(y);
 textbackground(black);
 textcolor(white);
 clrscr;
 checkbreak := true;
END.
(************************************************** ENDE ****************)